zanbur/app/build.gradle.kts

import java.io.FileInputStream
import java.util.Properties
import org.gradle.kotlin.dsl.android
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile



val keystoreProperties = Properties ()
keystoreProperties . load ( FileInputStream ( rootProject . file ("keystore.properties") ) )

plugins {
	id ("com.android.application") . version ("8.7.2")
	id ("org.jetbrains.kotlin.android") . version ("2.0.0")
	id ("org.jetbrains.kotlin.plugin.compose") . version ("2.0.0")
	id ("org.jetbrains.kotlin.plugin.serialization") . version ("2.0.0")
}

android {
	namespace = "com.kernelmaft.zanbur"
	compileSdk = 34

	defaultConfig {
		applicationId = "com.kernelmaft.zanbur"
		minSdk = 31
		targetSdk = 34
		versionCode = 1
		versionName = "1.0"
	}

	signingConfigs {
		create ("kernelmaft") {
			keyAlias = "kernelmaft"
			keyPassword = keystoreProperties ["keyPassword"] as String
			storeFile = file ( keystoreProperties ["storeFile"] as String )
			storePassword = keystoreProperties ["storePassword"] as String
		}
	}

	buildTypes {
		debug {
			signingConfig = signingConfigs . getByName ("kernelmaft")
		}
		release {
			isMinifyEnabled = true
			isShrinkResources = true
			signingConfig = signingConfigs . getByName ("kernelmaft")
		}
	}
	compileOptions {
		targetCompatibility = JavaVersion . VERSION_11
	}
	kotlinOptions {
		jvmTarget = "11"
	}
	buildFeatures {
		compose = true
	}
}

dependencies {
	// Android runtime libraries
	implementation ( "com.google.android.material" , "material" , "1.12.0" )
	implementation ( "androidx.activity" , "activity-compose" , "1.9.3" )
	implementation ( "androidx.core" , "core-ktx" , "1.13.1" )
	implementation ( "androidx.compose.material3" , "material3" , "1.3.1" )
	implementation ( "androidx.compose.ui" , "ui" , "1.7.5" )
	implementation ( "androidx.compose.ui" , "ui-graphics" , "1.7.5" )
	debugImplementation ( "androidx.compose.ui" , "ui-tooling" , "1.7.5" )
	implementation ( "androidx.datastore" , "datastore-preferences" , "1.1.1" )
	implementation ( "androidx.lifecycle" , "lifecycle-runtime-ktx" , "2.8.7" )
	implementation ( "org.jetbrains.kotlinx" , "kotlinx-coroutines-android" , "1.9.0" )
	implementation ( "org.jetbrains.kotlinx" , "kotlinx-serialization-json" , "1.7.3" )
	// Other libraries
	implementation ( "io.github.davidepianca98" , "kmqtt-common" , "0.4.8" )
	implementation ( "io.github.davidepianca98" , "kmqtt-client" , "0.4.8" )
}

tasks . withType ( KotlinCompile :: class ) . all {
	compilerOptions {
		freeCompilerArgs . addAll ("-opt-in=kotlin.ExperimentalUnsignedTypes")
	}
}